/*
This file was made by KnifeySpooney (http://www.spogg.com/KnifeySpooney). Do not copy or reproduce any part of this file without proper credit.
*/

/*
Make sure to add these components to your library:
--------------------------------------------------

Button
List
TextArea
TextInput
*/

import fl.controls.TextArea;
import fl.controls.TextInput;
import fl.controls.List;
import fl.data.DataProvider;
import fl.controls.Button;
import flash.display.Sprite;

setBG(0xDAFFCA);

var roomList:Array = new Array();
var usernameList:Array;
var pmuserList:Array;

var roomLeft = createButton("<", 30, 5, 4.3, false);
var roomRight = createButton(">", 30, 395, 4.3, false);
roomLeft.addEventListener(MouseEvent.CLICK, function() { moveRooms("left") } );
roomRight.addEventListener(MouseEvent.CLICK, function() { moveRooms("right") } );

var pushMsg:Button = createButton("Send", 68, 356, 376.7, true, false, 19);

var namesBtn:Button = createButton("User list", 80, 432, 5, true, true);
var pmsBtn:Button = createButton("PMs", 80, 512, 5, true, true);

var rand:int = Math.round(Math.random() * 899) + 100;
var username:String = "guest" + rand;
var usersex:String = "M";
var userage:String = "15";

var visibleRooms:Array = new Array;

loadLists();

var msgArea:TextArea = createTextBox(348, 420, 5, 25);
var inputMsg:TextInput = createTextField(19, 350, 6, 377);

var currentRoom:Object = createRoom("Global Chat", true);
var selectBtn:Object = namesBtn;
var selectRoom:Object = currentRoom.button;

for (var b:int=0; b<pmuserList.length; b++) {
	var pmName = /^[^\s]*/.exec(pmuserList[b]);
	createRoom(pmName);
}

roomList[5].history += "seagoat1984: Praise God!\n";
blinking(roomList[5]);

var tableList = createList(369, 160, 432, 25);

var message:String;

var namesList:DataProvider = new DataProvider();
var pmsList:DataProvider = new DataProvider();

updateLists();
updateChat();

stage.focus = inputMsg;
inputMsg.setSelection(inputMsg.text.length, inputMsg.text.length);

pushMsg.addEventListener(MouseEvent.CLICK, msgGO);
inputMsg.addEventListener(KeyboardEvent.KEY_DOWN, function(event:KeyboardEvent) { if (event.keyCode == Keyboard.ENTER) msgGO(event); } );
namesBtn.addEventListener(MouseEvent.CLICK, function(e:Event) { switchTabs(e.target) } );
pmsBtn.addEventListener(MouseEvent.CLICK, function(e:Event) { switchTabs(e.target) });

switchTabs(namesBtn);

function  msgGO(e:Event):void {
	var msg:String = stripTags(inputMsg.htmlText);
	if (msg != '') {
		if (msg.substr(0,1) == "/") {
			var cmd:String = /(?!\/)[^\s]*(?!\s)./i.exec(msg); // Returns anything after / and before the space.
			var params:String = msg.replace(/\/[^\s]*(?!\s).\s*/i, ""); // Removes /, the command, and the space.
			handleCommand(cmd, params);
		}
		else {
			msg = findLink(msg);
			msg = username + ": " + msg;
			sendMsg(msg);
		}
		inputMsg.htmlText = '';
		if (msgArea.verticalScrollPosition == msgArea.maxVerticalScrollPosition - 1)
			msgArea.verticalScrollPosition = msgArea.maxVerticalScrollPosition;
	}
	stage.focus = inputMsg;
	inputMsg.setSelection(inputMsg.text.length, inputMsg.text.length);
}

function sendMsg(message:String, server:Boolean=false):void {
	if (server) {
		message = "<font color='#FF0000'>* " + message + "</font>";
		for (var a:int=0; a<roomList.length; a++) {
			roomList[a].history += message + "\n";
		}
	}
	else
		currentRoom.history += message + "\n";
	updateChat();
}

function handleCommand(command:String, params:String):void {
	if (command == "nick" || command == "name") {
		params = params.replace(/[\s]/g, ""); // Removes spaces
		if (params != '') {
			sendMsg(username + " is now known as " + params, true);
			username = params;
			updateLists();
		}
		else
			sendMsg("Error: Invalid username. Username not changed.", true);
	}
	else if (command == "age") {
		params = params.replace(/[\s]/g, ""); // Removes spaces
		if (params != '' && parseInt(params)) {
			if (parseInt(params) < 100 && parseInt(params) > 0) {
				sendMsg("Your age has been changed to " + params, true);
				userage = params;
				updateLists();
			}
			else
				sendMsg("Error: Invalid age value. Possible values: 0-100. Age not changed.", true);
		}
		else
			sendMsg("Error: Invalid age value. Possible values: 0-100. Age not changed.", true);
	}
	else if (command == "sex" || command == "gender") {
		params = params.replace(/[\s]/g, ""); // Removes spaces
		if (params != '' && /^(m|f)$/i.test(params)) { // Checks for value M or F (case-insensitive)
			params = params.toUpperCase();
			sendMsg("Your gender has been changed to " + params, true);
			usersex = params;
			updateLists();
		}
		else
			sendMsg("Error: Invalid gender value. Possible values: M, F. Gender not changed.", true);
	}
	else if (command == "clear") {
		currentRoom.history = '';
		updateChat();
	}
	else if (command == "bg") {
		if (params != '' && /^(#|0x)[\w\d]{6}$/i.test(params))
			setBG(uint("0x" + params.replace(/^(#|0x)/i, "")));
		else
			sendMsg("Error: Invalid color value. Possible values: #NNNNNN, 0xNNNNNN. Background color not changed.", true);
	}
	else
		sendMsg("Command not recognized.", true);
}

function stripTags(str:String, tags:String=null):String {
	var pattern:RegExp = /<\/?[a-zA-Z0-9]+.*?>/gim;
        
	if (tags != null) {
		var getChars:RegExp = /(<)([^>]*)(>)/gim;
		var stripPattern:String = tags.replace(getChars, "$2|");
		stripPattern = stripPattern.substr(0, -1);
		stripPattern = "<(?!/?(" + stripPattern + ")(?=[^a-zA-Z0-9]))\/?[a-zA-Z0-9]+.*?/?>";
		pattern = new RegExp(stripPattern, "gim");
	}
	return str.replace(pattern, "");
}

function findLink(str:String):String {
	var regexp:RegExp = /(http:\/\/[^ ]+)+/gi; // Matches any text starting with http://
	return str.replace(regexp, "<a href='$1' target='_blank'><font color='#0000FF'><u>$1</u></font></a>");
}

function switchTabs(clickedTab:Object):void {
	selectBtn.selected = false;
	clickedTab.selected = true;
	selectBtn = clickedTab;
	
	if (clickedTab == namesBtn)
		tableList.dataProvider = namesList;
	if (clickedTab == pmsBtn)
		tableList.dataProvider = pmsList;
}

function switchRooms(clickedRoom:Object, room:Object):void {
	selectRoom.selected = false;
	currentRoom.scrollPos = msgArea.verticalScrollPosition;
	clickedRoom.selected = true;
	selectRoom = clickedRoom;
	msgArea.htmlText = room.history;
	msgArea.verticalScrollPosition = room.scrollPos;
	currentRoom = room;
}

function loadLists():void {
	usernameList = new Array("turtleturtle M8", 
							 "Viktor M32", 
							 "cr3t1n M13", 
							 "seagoat1984 M24", 
							 "PurpleHaze M17", 
							 "Stefango M44", 
							 "Ville M33", 
							 "AnnaZ F31", 
							 username + " " + usersex + userage);
	
	pmuserList = new Array("AnnaZ F31",
						   "Stefango M44",
						   "cr3t1n M13",
						   "Ville M33",
						   "seagoat1984 M24",
						   "turtleturtle M8");
}

function updateLists():void {
	loadLists();
	namesList = new DataProvider;
	for (var i:int=0; i<usernameList.length; i++) {
		namesList.addItem( { label:usernameList[i] } );
	}
	
	pmsList = new DataProvider;
	for (var a:int=0; a<pmuserList.length; a++) {
		pmsList.addItem( { label:pmuserList[a] } );
	}
	switchTabs(selectBtn);
}

function createRoom(label:String, selected:Boolean=false):Object {
	var rooms:int = roomList.length;
	
	var myButton:Button = new Button();
	if (selected)
		myButton.selected = true;
	myButton.label = label;
	myButton.toggle = true;
	myButton.width = 90;
	myButton.move(35 + (90 * visibleRooms.length), 4.3);
	
	if (visibleRooms.length < 4) {
		visibleRooms.push(myButton);
		addChild(myButton);
	}
	else {
		roomRight.enabled = true;
	}
	
	var newRoom:Object = { history: '', button: myButton, scrollPos: 0, isBlinking: false };
	newRoom.history = "<font color='#FF0000'>* Now chatting in room " + newRoom.button.label + "</font>\n";
	
	roomList.push(newRoom);
	myButton.addEventListener(MouseEvent.CLICK, function(e:Event) { switchRooms(e.target, newRoom); newRoom.isBlinking=false } );
	
	return newRoom;
}

function createButton(label:String, w:int, x:Number, y:Number, enabled:Boolean=true, selected:Boolean=false, h:int=22):Button {
	var myButton:Button = new Button();
	
	if (h)
		myButton.height = h;
	myButton.label = label;
	myButton.width = w;
	myButton.move(x, y);
	if (!enabled)
		myButton.enabled = false;
	if (selected)
		myButton.toggle = true;
	addChild(myButton);
		
	return myButton;
}

function createTextBox(h:int, w:int, x:Number, y:Number):TextArea {
	var textBox:TextArea = new TextArea();
	
	textBox.editable = false;
	textBox.wordWrap = true;
	textBox.width = w;
	textBox.height = h;
	textBox.move(x, y);
	
	addChild(textBox);
	return textBox;
}

function createTextField(h:int, w:int, x:Number, y:Number):TextInput {
	var textBox:TextInput = new TextInput();
	
	textBox.width = w;
	textBox.height = h;
	textBox.move(x, y);
	textBox.maxChars = 200;
	
	addChild(textBox);
	return textBox;
}

function createList(h:int, w:int, x:Number, y:Number):List {
	var list:List = new List;
	
	list.width = w;
	list.height = h;
	list.move(x, y);
	
	addChild(list);
	return list;
}

function blinking(room:Object):void {
	var delay:Number = 600;
	room.isBlinking = true;
	blink();
	
	function blink():void {
		if (room.isBlinking) {
			setTimeout(unBlink, delay);
			room.button.selected = true;
		}
	}
		
	function unBlink():void {
		if (room.isBlinking) {
			setTimeout(blink, delay);
			room.button.selected = false;
		}
	}
}

function moveRooms(dir:String):void {
	var visLength:int = visibleRooms.length;
	var lastVisRoom:int;
	
	for (var p:int=0; p<roomList.length; p++) {
		if (visibleRooms[0].label == roomList[p].button.label) {
			lastVisRoom = p;
			p = roomList.length;
		}
	}
	
	for (var a:int=0; a<visLength; a++) {
		removeChild(visibleRooms[a]);
	}
	
	visibleRooms = new Array();

	for (var j:int=0; j<visLength; j++) {
		if (dir == "right")
			b = j + (lastVisRoom + 1);
		if (dir == "left")
			b = j + (lastVisRoom - 1);
		roomList[b].button.move(35 + (90 * visibleRooms.length), 4.3);
		addChild(roomList[b].button);
		visibleRooms.push(roomList[b].button);
		updateChat();
	}
	
	if (visibleRooms[visibleRooms.length - 1].label == roomList[roomList.length-1].button.label)
		roomRight.enabled = false;
	if (visibleRooms[0].label == roomList[0].button.label)
		roomLeft.enabled = false;
		
	if (!roomLeft.enabled && dir == "right")
		roomLeft.enabled = true;
	if (!roomRight.enabled && dir == "left")
		roomRight.enabled = true;
}

function updateChat():void {
	switchRooms(selectRoom, currentRoom);
}

function setBG(color:uint):void {
	this.graphics.beginFill(color);
	this.graphics.drawRect(0, 0, 600, 400);
	this.graphics.endFill();
}